[fra700]

Salve Wesser, avrei bisogno di un aiuto con uno script che da le capacità di:

-far volare cj
-fargli apparire delle ali quando vola automaticamente (attraverso un file ifp caricato su gta3.img credo)
-quando comincia il volo cambia skin automaticamente(attraverso file dff e txd caricati su gta3.img)

La mia idea per uso personale ovviamente, è di sfruttare solo la prima opzione (quella in rosso), in modo da poterla assemblare più in là con lo skin selector (perché no?!).
Dunque mi rivolgo a te per una mano. Ho provato io stesso, ma a poco mandavo in tilt il pc tra crash e roba simile, quindi spero che tu possa aiutarmi.

{$CLEO}
0000:

while true
if 
  Player.Defined(0) // $PLAYER_CHAR == 0
then
0A8D: 30@ = read_memory 0x969110 size 4 virtual_protect 0
0A8D: 31@ = read_memory 0x969114 size 2 virtual_protect 0
if 
    05AE:   30@s == "IATUOJ" // @s == 'short'
then
    0A8C: write_memory 0x969110 size 4 value 0x0 virtual_protect 0 
    04ED: load_animation "SKJOUTAI"
    023C: load_special_actor 'SASUKE3' as 5 // models 290-299 
    038B: load_requested_models 

    while true
    if and 
    84EE: not animation "SKJOUTAI" loaded
    823D:   not special_actor 5 loaded 
    jf break    
     wait 0
    end
    00A0: store_actor $PLAYER_ACTOR position_to 27@ 28@ 29@ 
    095C: create_smoke_at 27@ 28@ 29@ velocity 0.0 0.0 0.05 RGBA 1.0 1.0 1.0 1.0 size 1.0 last_factor 0.1
    09C7: change_player $PLAYER_CHAR model_to #SPECIAL05 
    0296: unload_special_actor 5 

    while true
    if and
    00E1:   player 0 pressed_key 4 // action
    00E1:   player 0 pressed_key 14 //  jump
    then
        023C: load_special_actor 'SASUKEW' as 6 // models 290-299 
        0247: load_model 1582 
        038B: load_requested_models 

        while true 
        if and
        823D:   not special_actor 6 loaded 
        8248:   not model 1582 available 
        jf break
         wait 0
        end
        02AB: set_actor $PLAYER_ACTOR immunities BP 0 FP 0 EP 1 CP 1 MP 0 
        0992: set_player $PLAYER_CHAR weapons_scrollable 0 
        01B9: set_actor $PLAYER_ACTOR armed_weapon_to 0 
        0172: 8@ = actor $PLAYER_ACTOR Z_angle
        0812: AS_actor $PLAYER_ACTOR perform_animation "sasuke_01" IFP_file "SKJOUTAI" 1.0 loopA 1 lockX 0 lockY 0 lockF 1 time -1 // versionB 
        083C: set_actor $PLAYER_ACTOR velocity_in_direction_XYZ 0.0 0.0 20.0 
        wait 900
        04C4: store_coords_to 27@ 28@ 29@ from_actor $PLAYER_ACTOR with_offset 0.0 0.0 1.0 
        009A: 26@ = create_actor_pedtype 8 model #SPECIAL06 at 27@ 28@ 29@ 
        02AB: set_actor 26@ immunities BP 1 FP 1 EP 1 CP 1 MP 1 
        0619: enable_actor 26@ collision_detection 0 
        0489: set_actor 26@ muted 1 
        0296: unload_special_actor 6 
        
        0107: 25@ = create_object 1582 at 27@ 28@ -25.0 
        0382: set_object 25@ collision_detection 0 
        04D9: object 25@ set_scripted_collision_check 0 
        08D2: object 25@ scale_model 0.01 
        0177: set_object 25@ Z_angle_to 8@ 
        0249: release_model 1582 
        
        069B: attach_object 25@ to_actor $PLAYER_ACTOR with_offset -0.088 0.27 0.295 rotation 0.0 0.0 0.0 
        04F4: put_actor 26@ into_turret_on_object 25@ offset_from_object_origin 0.0 0.0 -0.5 orientation 0 both_side_angle_limit 0.0 lock_weapon 1 
        0812: AS_actor 26@ perform_animation "sasuke_02" IFP_file "SKJOUTAI" 1.0 loopA 1 lockX 0 lockY 0 lockF 1 time -1 // versionB 
        9@ = 1.0        
        19@ = 50.0

        while true
        0494: get_joystick 0 data_to 17@ 18@ 22@ 22@ 
        0093: 17@ = integer 17@ to_float 
        0093: 18@ = integer 18@ to_float 
        0013: 17@ *= -1.0 
        0087: 20@ = 17@ // (float) 
        0087: 21@ = 18@ // (float) 
        0097: make 18@ absolute_float 

        0017: 19@ /= 1750.0 
        006B: 17@ *= 19@ // (float) 
        006B: 18@ *= 19@ // (float) 
        005B: 8@ += 17@ // (float) 
        0017: 18@ /= 6.5 

        if
        00E1:   player 0 pressed_key 1    /// forward/backward
        then
            if
            0.0 > 21@
            then
                005B: 9@ += 18@ // (float) 
                //9@ += 0.5
                if
                9@ > 14.9
                then
                    9@ = 15.0
                end
            else
                if
                21@ > 0.0
                then
                    
                    0063: 9@ -= 18@ // (float) 
                    //9@ += -0.5
                    if
                    0.5 > 9@
                    then
                        9@ = 0.5
                    end
                    
                end
            end
        else
            //0063: 9@ -= 18@ // (float) 
            9@ += -0.6 
            if
            0.5 > 9@
            then
                9@ = 0.5
            end
            
        end

        if
        00E1:   player 0 pressed_key 0    /// left/right
        then
            if
             0.0 > 20@
            then
                2@ += 3.5
                if
                2@ > 35.0
                then
                    2@ = 35.0
                end
            else
                if
                 20@ > 0.0
                then
                    2@ -= 3.5 
                    if
                    -35.0 > 2@
                    then
                        2@ = -35.0
                    end
                end
            end
        else
            if
             2@ > 0.0
            then
                2@ -= 2.5 
                if
                0.0 > 2@
                then
                    2@ = 0.0
                end 
            end
            if
             0.0 > 2@
            then
                2@ += 2.5
                if
                 2@ > 0.0
                then
                    2@ = 0.0
                end 
            end
        end

            0007: 7@ = 29.0
            0087: 6@ = 9@ // (float)
            0013: 6@ *= 2.0
            0063: 7@ -= 6@ // (float)
            if
            0.0 > 7@
            then
                7@ = 0.0
            end
            if
            7@ > 27.0
            then
                7@ = 30.0
            end
            0173: set_actor $PLAYER_ACTOR Z_angle_to 8@
            083E: set_actor $PLAYER_ACTOR rotation 7@ 2@ 8@ while_in_air 

            04C4: store_coords_to 10@ 11@ 12@ from_actor $PLAYER_ACTOR with_offset 0.0 9@ 0.1 
            00A0: store_actor $PLAYER_ACTOR position_to 13@ 14@ 15@ 
            0063: 10@ -= 13@ // (float) 
            0063: 11@ -= 14@ // (float) 
            0063: 12@ -= 15@ // (float) 
            083C: set_actor $PLAYER_ACTOR velocity_in_direction_XYZ 10@ 11@ 12@ 

        0819: 16@ = actor $PLAYER_ACTOR distance_from_ground 
        if or
        1.9 > 16@
        00E1:   player 0 pressed_key 15 // enter
        then
            009B: destroy_actor 26@ 
            0108: destroy_object 25@
            break
        end
        19@ = 50.0

         wait 0
        end
        0173: set_actor $PLAYER_ACTOR Z_angle_to 8@
        0792: disembark_instantly_actor $PLAYER_ACTOR 
        0992: set_player $PLAYER_CHAR weapons_scrollable 1 
        02AB: set_actor $PLAYER_ACTOR immunities BP 0 FP 0 EP 0 CP 0 MP 0 


    end

    0A8D: 30@ = read_memory 0x969110 size 4 virtual_protect 0
    0A8D: 31@ = read_memory 0x969114 size 2 virtual_protect 0
    if 
        05AE:   30@s == "IATUOJ" // @s == 'short'
    then
        0A8C: write_memory 0x969110 size 4 value 0x0 virtual_protect 0 
        04EF: release_animation "SKJOUTAI"
        break    
    end
     wait 0
    end
    00A0: store_actor $PLAYER_ACTOR position_to 27@ 28@ 29@ 
    095C: create_smoke_at 27@ 28@ 29@ velocity 0.0 0.0 0.05 RGBA 1.0 1.0 1.0 1.0 size 1.0 last_factor 0.1
    09C7: change_player $PLAYER_CHAR model_to #NULL 
    0792: disembark_instantly_actor $PLAYER_ACTOR 
    wait 1000
    
end
end
 wait 0
end

[fra700]

Scusate il doppio post...

Qualcun altro saprebbe aiutarmi?

[fra700]

Molte volte si resta più contenti nel trovare scritto: non ti aiuto vai a cagare, piuttosto che essere interamente ignorati!(ovviamente non mi riferisco agli utenti che non hanno un ruolo in quest'area)

[Wesser]

Ho appena dato un'occhiata al tuo profilo per rendermi conto di quale persona matura abbia di fronte, in base all'età. Sono rimasto allibito dopo aver appurato il fatto che dovresti aver almeno imparato gli ingredienti fondamentali per evitare contrasti con gli altri utenti. D'altronde, non dovrei essere io ad insegnarteli avendo un'età inferiore.

Il topic è LIBERO, il ché significa che qualsiasi utente può contribuire aiutando chicchessia. Pare che tu ti riferisca proprio alla mia persona, e ciò è abbastanza irritante.

Ho 2 vite da dover condurre, ed il tempo si riduce sempre più. Ora, sono in procinto di frequentare l'università e mi sono preparato per un test, evitando di avere un debito formativo e frequentare i pre-corsi.

Questa tua arroganza non comprometterà affatto la mia futura decisione di non aiutarti. Lo farò sé e quando avrò tempo. Sono un tipo pacifico, che dimentica il passato, altrimenti avrei tanti rimorsi da dover rispolverare. Sì và avanti, non nella direzione opposta: ciò che è passato, è passato.

Te lo dico da padre (non sono neanche fidanzato ) ma potrei essere tuo fratello minore.

[fra700]

A dire il vero non so quante persone si occupano di quest'area. Non pretendo il tuo aiuto, mi dispiaccio solo di essere stato scartato (non mi dilungo non saprei che scrivere XD).
Un'ultima cosa... avrei voluto evitare queste frasi, in genere la mia mente distingue benissimo l'importanza dall'insignificanza.
Sappi solo una cosa: un computer condiviso non produce nulla di buono. Io non conosco le tue circostanze nella vita reale ovviamente, di conseguenza tu non conosci le mie. Con questa chiudo e ti chiedo scusa.

[peppetrack93]

Salve a tutti, Come faccio a fare un cancello che quando mi avvicino si apre e quando mi allontano si chiude???

[Carl Vercetti Bellic]

Salve, avrei bisogno, diciamo di una mod realistica, tipo, cj si alza la mattina fa colazione, poi va a lavoro (il lavoro si sceglie) torna a casa, si fa un giro con gli amici, cena e va a dormire. Poi magari ogni tanto, succede qualcosa, scoppiano guerre, lo rapiscono, lo rapinano. Magari si licenzia, viene assunto in politica e diventa presidente dittatore kebbabbaro XD. Si potrebbe?

[McClane]

Allora ho un idea su una mod da creare con Sanny Builder. Vorrei che mi spiegaste alcune cose,tipo se posso non mettere gli opcodes all'inizio di alcune righe di codice (senza dare errore durante la compilazione).

Vorrei in tutto creare una mod dove CJ raggiunge un luogo dove c'è un marker rosso e gli appare un menu dove può comprare della droga per poi rivenderla a un NPC fisso presente in vari punti della mappa.

Gentilissimo chi mi aiuta in modo preciso e conciso.

[Frak]

[CLEO]

L'icona 55 del radar è la macchinina blu, come mostra la screen sotto. Quale icona ha l'id dell'aereo del Cimitero Degli Aerei? Dico l'icona delle missioni di Toreno: Stowaway, N.O.E. e le altre...



Poi in questa screen vedete il marker rosso? Voglio ridimensionarlo e farlo diventare più grande: ecco le stringhe riguardanti quel marker:

0570: 20@ = create_asset_radar_marker_with_icon 55 at 357.7354 2504.556 16.4844
 
8100: not actor $PLAYER_ACTOR in_sphere 357.7354 2504.556 16.4844 radius 1.5 1.5 1.0 sphere 0 in_car

Poi se sbaglio ditemelo

Sto modificando la mod della benzina... da come si vede e non riesco a modificare la grandezza di quel marker. L'icona
non conta molto, ma di più il marker, perché se ci atterro su con un aereo è troppo piccolo per fare rifornimento.

PS: Per le icone ho risolto.

Messaggio modificato da Frak il 27 settembre 2011 - 16:56

[Frak]

Up

[Fabio206]

Gli up dopo 48 ore come scritto nel regolamento del forum

[Frak]

pensavo 24 e poi sono impaziente

[Shyne]

Frak, il 27 settembre 2011 - 15:15 ha detto:

...
Poi in questa screen vedete il marker rosso? Voglio ridimensionarlo e farlo diventare più grande: ecco le stringhe riguardanti quel marker:

0570: 20@ = create_asset_radar_marker_with_icon 55 at 357.7354 2504.556 16.4844
 
8100: not actor $PLAYER_ACTOR in_sphere 357.7354 2504.556 16.4844 radius 1.5 1.5 1.0 sphere 0 in_car

...

Ciao, di script non ne so molto, ma comunque se è uguale agli enex prova a mettere "... radius 3.0 3.0 1.0 ..." doivrebbe venire più grande il cerchio.

Per gli id delle icone le puoi trovare in sanny builder, sopra nella "guida in linea" in "aiuto" li dice tutti gli id delle armi, icone, numeri dei tasti, id dei vestiti e molto altro.

[McClane]

{$CLEO .cs}

//------MAIN------

:MAIN
03A4: name_thread 'main'
0247: load_model #WMYDRUG
038B: load_requested_models

//:LOAD_ANIMS
//04ED: load_animation "DEALER_DEAL"
//repeat
//wait 0 ms
//until 04EE: animation "DEALER_DEAL" loaded

:CHECK_DEALERS
wait 0 ms
if
  0248: model #WMYDRUG available
jf @CHECK_DEALERS

:SPAWN_DEALERS
009A: 1@ = create_actor_pedtype 17 model #WMYDRUG at 400.5016 -2053.4592 7.8359 //SANTA MARIA BEACH  
0187: 0@ = create_marker_above_actor 1@
0165: set_marker 0@ color_to 1
0249: release_model #WMYDRUG
0A93: end_custom_thread

Il gioco si blocca appena mi avvicino all'attore spawnato.

[Frak]

Shyne, il 29 settembre 2011 - 01:38 ha detto:

Frak, il 27 settembre 2011 - 15:15 ha detto:

...
Poi in questa screen vedete il marker rosso? Voglio ridimensionarlo e farlo diventare più grande: ecco le stringhe riguardanti quel marker:

0570: 20@ = create_asset_radar_marker_with_icon 55 at 357.7354 2504.556 16.4844
 
8100: not actor $PLAYER_ACTOR in_sphere 357.7354 2504.556 16.4844 radius 1.5 1.5 1.0 sphere 0 in_car

...

Ciao, di script non ne so molto, ma comunque se è uguale agli enex prova a mettere "... radius 3.0 3.0 1.0 ..." doivrebbe venire più grande il cerchio.

Per gli id delle icone le puoi trovare in sanny builder, sopra nella "guida in linea" in "aiuto" li dice tutti gli id delle armi, icone, numeri dei tasti, id dei vestiti e molto altro.

Grazie comunque per gli ID ho risolto perché sono andato su SA-MP Wiki dove speravo che c'era la lista. E così è, c'è la lista.

[Wesser]

Premesso che d'ora in poi non accetterò più richieste (personalmente), per via di progetti ben più complessi da portare avanti, cercherò di soddisfare le vostre domande più recenti.

@fra700, scuse accettate o perlomeno circostanze assecondate. Purtroppo, ti ho preparato solo lo script senza animazione, poiché quì si parla solo di scripting e, dopotutto, non creo animazioni su richiesta (avrei bisogno anche di un oggetto da animare che non so come si possa implementare in GTA). Ecco il sorgente:

{$CLEO}

0000: NOP

// Script configuration settings
17@ = 179  // Player flying cloth ID (WMYAMMO)
18@ = 1548 // Player flying wings ID (CJ_DRIP_TRAY)

// Make sure parachute.ifp is always loaded
04ED: load_animation "PARACHUTE" 
while 84EE:  not animation "PARACHUTE" loaded
  wait 0 
end
//04EF: release_animation "PARACHUTE" 

while true
  wait 0 
  if and
  03EE:  player $PLAYER_CHAR controllable
  80DF:  not actor $PLAYER_ACTOR driving
  8818:  not actor $PLAYER_ACTOR in_air
  84AD:  not actor $PLAYER_ACTOR in_water
  then
    0@ = 0x969110 // cLastKeysBuffer[32]
    0A8D: 1@ = read_memory 0@ size 4 virtual_protect 0 
    000A: 0@ += 0x4 
    0A8D: 2@ = read_memory 0@ size 2 virtual_protect 0 
    if and
      1@ == 0x59494E47 // YING
      2@ == 0x464C // FL
    then
      03E5: text_box 'CHEAT1' // Cheat activated
      0@ -= 0x4 
      0A8C: write_memory 0@ size 4 value 0 virtual_protect 0 
      0@ += 0x4 
      0A8C: write_memory 0@ size 2 value 0 virtual_protect 0 
      083C: set_actor $PLAYER_ACTOR velocity_in_direction_XYZ 0.0 0.0 10.0 
      wait 500 
      // Load ped and wings model IDs
      0247: load_model 17@ 
      0247: load_model 18@ 
      038B: load_requested_models
      0665: get_actor $PLAYER_ACTOR model_to 14@ 
      09C7: change_player $PLAYER_CHAR model_to 17@ 
      0107: 15@ = create_object 18@ at 0.0 0.0 0.0 
      069B: attach_object 15@ to_actor $PLAYER_ACTOR with_offset 0.0 0.275 0.1875 rotation 0.0 0.0 0.0 
      0249: release_model 17@ 
      0249: release_model 18@ 
      5@ = 0.0 // zenith
      6@ = 0.0 // azimuth
      7@ = 0.0 // radius
      while true
        wait 0 
        0A96: 0@ = actor $PLAYER_ACTOR struct
        0@ += 0xB9 
        0A8D: 3@ = read_memory 0@ size 1 virtual_protect 0 // bCollidingEntityType
        0819: 4@ = actor $PLAYER_ACTOR distance_from_ground
        if and
          3@ == 0 
          4@ > 2.0 
        8118:  not actor $PLAYER_ACTOR dead
        84AD:  not actor $PLAYER_ACTOR in_water
        then
          if 
          00E1:  player 0 pressed_key 16 // Sprint
          then
            if 
            8611:  not actor $PLAYER_ACTOR performing_animation "FALL_SKYDIVE_ACCEL" 
            then
              0812: AS_actor $PLAYER_ACTOR perform_animation "FALL_SKYDIVE_ACCEL" IFP_file "PARACHUTE" 4.0 loopA 1 lockX 0 lockY 0 lockF 0 time -1 // versionB
              0650: destroy_particle 16@ 
              0669: 16@ = attach_particle "overheat_car" to_actor $PLAYER_ACTOR with_offset 0.0 0.0 0.0 flag 1 
              064C: make_particle 16@ visible
              7@ = 25.0 
            end
          else
            if 
            8611:  not actor $PLAYER_ACTOR performing_animation "FALL_SKYDIVE" 
            then
              0812: AS_actor $PLAYER_ACTOR perform_animation "FALL_SKYDIVE" IFP_file "PARACHUTE" 4.0 loopA 1 lockX 0 lockY 0 lockF 0 time -1 // versionB
              0650: destroy_particle 16@ 
              0669: 16@ = attach_particle "explosion_door" to_actor $PLAYER_ACTOR with_offset 0.0 0.0 0.0 flag 1 
              064C: make_particle 16@ visible
              7@ = 10.0 
            end
          end
          0494: get_joystick 0 data_to 1@ 2@ 3@ 4@ 
          0093: 1@ = integer 1@ to_float
          1@ *= 0.0375 
          0172: 5@ = actor $PLAYER_ACTOR Z_angle
          0063: 5@ -= 1@ 
          0093: 2@ = integer 2@ to_float
          2@ *= 0.0375 
          005B: 6@ += 2@ 
          if 
            6@ > 75.0 
          then
            6@ = 75.0 
          else
            if 
              6@ < -75.0 
            then
              6@ = -75.0 
            end
          end
          1@ *= 5.0 
          083E: set_actor $PLAYER_ACTOR rotation 6@ 1@ 5@ while_in_air
          // Get counterclockwise angle
          5@ *= -1.0 
          5@ += 360.0 
          02F6: 11@ = sine 5@ 
          02F7: 12@ = cosine 5@ 
          006B: 11@ *= 7@ 
          006B: 12@ *= 7@ 
          02F6: 8@ = sine 6@ 
          02F7: 9@ = cosine 6@ 
          006B: 11@ *= 9@ 
          006B: 12@ *= 9@ 
          0087: 13@ = 7@ 
          006B: 13@ *= 8@ 
          13@ += 0.325 
          00A0: store_actor $PLAYER_ACTOR position_to 8@ 9@ 10@ 
          if 
            10@ >= 350.0 // flying height limit
          then
            13@ *= -20.0 
          end
          083C: set_actor $PLAYER_ACTOR velocity_in_direction_XYZ 11@ 12@ 13@ // about 0.82625z to lock
        else
          if 
            14@ <> #NULL 
          then
            0247: load_model 14@ 
            038B: load_requested_models
          end
          09C7: change_player $PLAYER_CHAR model_to 14@ 
          0249: release_model 14@ 
          0108: destroy_object 15@ 
          0650: destroy_particle 16@ 
          0172: 5@ = actor $PLAYER_ACTOR Z_angle
          083C: set_actor $PLAYER_ACTOR velocity_in_direction_XYZ 0.0 0.0 0.0 
          0687: clear_actor $PLAYER_ACTOR task
          0173: set_actor $PLAYER_ACTOR Z_angle_to 5@ 
          break
        end
      end
    end
  end
end

Digita "FLYING" e durante il volo premi SHIFT (di default) per sprintare. Ovviamente, utilizza i tasti direzionali per muoverti nelle varie direzioni ed andare SU e GIU' rispettivamente con le freccette AVANTI ed INDIETRO. Puoi cambiare il modello del player o delle ali modificando le variabili locali 17@ e 18@, poste all'inizio del codice.

@peppetrack93, se vuoi inserire un unico cancello, puoi attenerti a questo script:

{$CLEO}

1@ = 2488.562 // x coord
2@ = -1666.865 // y coord
3@ = 12.8757 // z coord
3@ -= 0.5 // coord adjust

0247: load_model 988 
while 8248:  not model 988 available
  wait 0 
end
//0249: release_model 988 

0107: 0@ = create_object 988 at 1@ 2@ 3@ 
0400: store_coords_to 4@ 5@ 6@ from_object 0@ with_offset -6.1 0.0 0.0 

while true
  wait 0 
  if 
  00FE:  actor $PLAYER_ACTOR sphere 0 in_sphere 1@ 2@ 3@ radius 5.0 5.0 5.0 
  then
    if
    84E6:  not object 0@ near_point 4@ 5@ 6@ radius 1.0 1.0 1.0 flag 0 
    then
      034E: move_object 0@ to 4@ 5@ 6@ speed 0.1 0.1 0.0 flag 1 
    end
  else
    if
    84E6:  not object 0@ near_point 1@ 2@ 3@ radius 1.0 1.0 1.0 flag 0 
    then
      034E: move_object 0@ to 1@ 2@ 3@ speed 0.1 0.1 0.0 flag 1 
    end
  end
end

Modifica le coordinate XYZ delle prime 3 variabili locali per cambiare il luogo dello spawn. Se hai intenzione di aggiungerne altri, dovrei creare uno script un po' più complesso che necessita una conoscenza degli array da parte tua. Questo è il motivo per cui non ti ho già mostrato il codice più complesso.

@Carl Vercetti Bellic, non mi dilungo molto in chiacchiere. Il tutto è fattibile, ma chi perderebbe del tempo ad ideare un'idea così dispendiosa di tempo se non propria?

@Frak, come ti ha giustamente suggerito @Shyne, dalla barra dei menu del Sanny Builder, vai su Aiuto->Guida in linea->SCM Documentation->GTA SA. Quì troverai tutto il materiale inerente ai vari valori e constanti di alcuni parametri. Per quanto concerne il raggio (radius) del marker rosso, quei 3 parametri indicano le dimensioni in 3D (larghezza, lunghezza ed altezza) della "sfera" rossa, appunto. Di solito, i primi 2 parametri non variano poiché, trattandosi di una figura circolare, la circonferenza è interamente equidistante dal centro (parlando di figure piane 2D).

@McClane, questo script dovrebbe funzionare come previsto:

{$CLEO}

0000: NOP

018A: 1@ = create_checkpoint_at 400.5016 -2053.4592 7.8359 
//00BC: show_text_highpriority GXT "GXTTKEY" time 5000 flag 1 

while true
  wait 0 
  if 
  00FE:  actor $PLAYER_ACTOR sphere 0 in_sphere 400.5016 -2053.4592 7.8359 radius 50.0 50.0 50.0 
  then
    0164: disable_marker 1@ 
    //00BC: show_text_highpriority GXT "GXTTKEY" time 5000 flag 1 
    0247: load_model #WMYDRUG 
    038B: load_requested_models
    {while 8248:  not model #WMYDRUG available
      wait 0 
    end}
    009A: 0@ = create_actor_pedtype 17 model #WMYDRUG at 400.5016 -2053.4592 7.8359 // SANTA MARIA BEACH
    0187: 1@ = create_marker_above_actor 0@ 
    0165: set_marker 1@ color_to 1 
    0249: release_model #WMYDRUG 
    0A93: end_custom_thread
  end
end

[Frak]

Grazie Wesser

Ma nooooo è una figata ci sta scritto tutto

Messaggio modificato da Frak il 30 settembre 2011 - 15:31

[eow92]

Salve ragazzi! mi hanno detto di postare qui questa mi richiesta, allora in riferimento alla mod che apre le porte dell'area 69, vi volevo chiededere se qualcuno sa come posso trovare le sigle, o gli ID, degli oggetti da spostare! non ho prp la piu pallida idea... :S mi scuso se ho postato la richiesta in un altro topic...

[fra700]

Ti chiedo scusa personalmente per prima, sono stato egoista, ora me ne sono reso conto, soprattutto perché non ti sei tirato indietro.
Riguardo lo script grazie per l'attenzione. In realtà l'animazione di quello script io la possiedo già, si chiama "skjoutai.ifp" (quindi non servirebbe creare una seconda anim.). Le mie intenzioni erano semplicemente quelle di eliminare la parte di script che trasforma il mio cj nel ped "sasuke3" e l'altro pezzo che gli fa apparire le ali "sasukew".

Prova ad immaginare:
Script attuale = CJ -> digito key -> si trasforma in nel ped sasuke + gli vengono date delle ali -> vola;
Script che vorrei = CJ -> digito key -> vola.

Posso tranquillamente assemblare lo script alla mia animazione? devo per caso sostituire ogni parola "Parachute" con "skjoutai" per farlo? E cosi facendo risulterebbe lo stesso effetto dello script principale? (se ci fai caso nello script c'è anche un limite di quota, vorrei tenerlo).

Scusa se domando troppo.

Messaggio modificato da fra700 il 02 ottobre 2011 - 16:27

[Wesser]

@eow92, puoi formulare meglio la domanda? Non ho capito bene.

@fra700, anche tu non sei stato chiaro. Elencami le varie modifiche da apportare per filo e per segno. E comunque, puoi postare quante richieste vuoi quì.