[Automan]

Premetto che in Sanny ci sono gli elenchi di utilità di SA, in:
Aiuto/Guida in linea/SCM Documentation/GTA SA
come ad esempio il tipo di peds.
E in: Strumenti/Strumenti IDE/Ricerca opcode
puoi trovare e cercare i comandi.
Per esempio se cerchi 'set_actor', trovi il settaggio dei peds, per esempio la vita.

Se riesci a trovare qualcosa da utilizzare come discoteca, per i peds ballerini servono:
1) musica.
2) l'animazione di ballo.

-musica:
Ci sono 2 metodi.
Il primo consiste di mettere una musica fissa, del gioco, negli IPL, come se fosse un oggetto:

auzo
LAPDM1, 10, 1, 2224.23, -1182.74, 1029.80, 15
end

lapdm1 è il tag, si può mettere quello che si vuole.
Io ho fatto riferimento al ped.
Il 15 finale è il raggio di diffusione.
Si potrebbero mettere tante stringhe quante sono le casse di diffusione, per esempio.
Il secondo metodo è gestire una musica personale con Cleo.
Va messa, in mp3, nella cartella: GTA San Andreas User Files/User Tracks
O in una propria cartella, ma sempre in GTA San Andreas User Files.
Nota: Questa directory per Cleo è 1. Quella del gioco è 0.
Bisogna sempre gestire, dire a cleo, dove andare a prendere la roba, altrimenti il gioco crasha.
Gli script cleo sono di due tipi, .cs, quelli usuali, e i .cm, che vengono richiamati all'interno dei .cs.
Se c'è della musica, ma poi deve essere richiamato un .cm, allora:

0A99: chdir 0
0A94: start_custom_mission "m3\M3_K99m62"

dove m3 è la cartella dei .cm nella cartella Cleo, o qualsiasi altra cartella.

Pertanto:

0A99: chdir 1 
0AAC: 0@ = load_mp3 "User Tracks\quiet.mp3" 
// non occorre attendere il caricamento, per i file suoni.
0AAD: set_mp3 0@ perform_action 1
---

0AAD: set_mp3 0@ perform_action 0
0AAE: release_mp3 0@
0A99: chdir 0

-ballo:

04ED: load_animation "DANCING"
// Nota: le eventuali animazioni del file "PED" non si caricano!
:loadcheck
0001: wait 0 ms
if
04EE:   animation "DANCING" loaded
004D: jump_if_false @loadcheck

---

009A: 1@ = create_actor_pedtype 4 model #LAPDM1 at 2224.23 -1182.74 1029.80
0605: actor 1@ perform_animation_sequence "DAN_LOOP_A" IFP_file "DANCING" 4.0 loop 1 0 0 0 time -1

---
// eventuale stop animazione, ped fermo in piedi:
05B9: AS_actor $PLAYER_ACTOR stay_idle 1 ms
// alcune animazioni sono state inserite in comandi.
---

04EF: release_animation "DANCING"

Prova alcune sequenze, per vedere quella che va meglio.
Potrebbero essere anche diverse per gruppo di peds.
Descrizioni file animazioni da scaricare:
http://www.mediafire..._animazioni.rar

[MyloveGTA]

scusami Auto :c mi faresti direttamente un codice completo cleo? :c sono una rottura :\ dove tipo ci stanno 7/8 persone che ballano, per la musica anche se non ho capito mi accontenterò di non averla c:P.S Si in sanny ho visto alcuni code ma non ci capisco ancora molto e quello che faccio non viene a fungere

[Automan]

Comunque complimenti, perché di modder in rosa su GTA non ne ho mai vista una in tutto il mondo!

Purtroppo oltre a non avere molto tempo, uno script generico è difficile da fare...
Occorre scegliere il tipo di peds, dove si trovano, che animazioni dargli, e che tipo di musica mettere.
Mi dovresti almeno dire se hai una musica tua, o vuoi usare quella standard da mettere negli IPL...

[MyloveGTA]

Automan, il 07 luglio 2015 - 09:40 ha detto:

Comunque complimenti, perché di modder in rosa su GTA non ne ho mai vista una in tutto il mondo!

haha Grazie, io no una musica normale, non ha molta importanza ti ringrazio anzi che presti i tuoi umili servigi

Purtroppo oltre a non avere molto tempo, uno script generico è difficile da fare...
Occorre scegliere il tipo di peds, dove si trovano, che animazioni dargli, e che tipo di musica mettere.
Mi dovresti almeno dire se hai una musica tua, o vuoi usare quella standard da mettere negli IPL...

[Automan]

{$CLEO}
0000:
// lo script si avvia se il player entra in un cubo di 100 metri dal centro della scena. Termina se vi esce. MAI attivare uno script sempre e comunque.
:START
0001: wait 0 ms
if
00FE:   actor $PLAYER_ACTOR sphere 0 in_sphere 757.74 -2840.03 10.68 radius 100.0 100.0 100.0
004D: jump_if_false @START

// 4 maschi e 4 femmine, da scegliere diversi.
0247: load_model #WMYST
0247: load_model #WMYST
0247: load_model #WMYST
0247: load_model #WMYST
0247: load_model #WMYST
0247: load_model #WMYST
0247: load_model #WMYST
0247: load_model #WMYST
:loadcheck
0001: wait 0 ms
if and
0248:   model #WMYST  available
0248:   model #WMYST  available
0248:   model #WMYST  available
0248:   model #WMYST  available
0248:   model #WMYST  available
0248:   model #WMYST  available
0248:   model #WMYST  available
0248:   model #WMYST  available
004D: jump_if_false @loadcheck
// nota: gli if and-or possono essere al massimo 8.

04ED: load_animation "DANCING"
// nota: le eventuali animazioni del file "PED" non si caricano.
:loadcheck2
0001: wait 0 ms
if
04EE:   animation "DANCING" loaded
004D: jump_if_false @loadcheck2

009A: 1@ = create_actor_pedtype 4 model #WMYST at 754.77 -2817.23 2.30
0173: set_actor 1@ Z_angle_to -90.0 // -90 è est, 90 è ovest. 0 nord, 180 sud.
009A: 2@ = create_actor_pedtype 4 model #WMYST at 754.77 -2817.23 2.30
0173: set_actor 2@ Z_angle_to -90.0 // -90 è est, 90 è ovest. 0 nord, 180 sud.
009A: 3@ = create_actor_pedtype 4 model #WMYST at 754.77 -2817.23 2.30
0173: set_actor 3@ Z_angle_to -90.0 // -90 è est, 90 è ovest. 0 nord, 180 sud.
009A: 4@ = create_actor_pedtype 4 model #WMYST at 754.77 -2817.23 2.30
0173: set_actor 4@ Z_angle_to -90.0 // -90 è est, 90 è ovest. 0 nord, 180 sud.
009A: 5@ = create_actor_pedtype 4 model #WMYST at 754.77 -2817.23 2.30
0173: set_actor 5@ Z_angle_to -90.0 // -90 è est, 90 è ovest. 0 nord, 180 sud.
009A: 6@ = create_actor_pedtype 4 model #WMYST at 754.77 -2817.23 2.30
0173: set_actor 6@ Z_angle_to -90.0 // -90 è est, 90 è ovest. 0 nord, 180 sud.
009A: 7@ = create_actor_pedtype 4 model #WMYST at 754.77 -2817.23 2.30
0173: set_actor 7@ Z_angle_to -90.0 // -90 è est, 90 è ovest. 0 nord, 180 sud.
009A: 8@ = create_actor_pedtype 4 model #WMYST at 754.77 -2817.23 2.30
0173: set_actor 8@ Z_angle_to -90.0 // -90 è est, 90 è ovest. 0 nord, 180 sud.

0001: wait 250 ms  
// Occorre del tempo al pgm per spawnare il ped, ma non esiste nessun controllo per questo, al contrario del load.

0605: actor 1@ perform_animation_sequence "DAN_LOOP_A" IFP_file "DANCING" 4.0 loop 1 0 0 0 time -1
0605: actor 2@ perform_animation_sequence "DAN_LOOP_A" IFP_file "DANCING" 4.0 loop 1 0 0 0 time -1
0605: actor 3@ perform_animation_sequence "DAN_LOOP_A" IFP_file "DANCING" 4.0 loop 1 0 0 0 time -1
0605: actor 4@ perform_animation_sequence "DAN_LOOP_A" IFP_file "DANCING" 4.0 loop 1 0 0 0 time -1
0605: actor 5@ perform_animation_sequence "DAN_LOOP_A" IFP_file "DANCING" 4.0 loop 1 0 0 0 time -1
0605: actor 6@ perform_animation_sequence "DAN_LOOP_A" IFP_file "DANCING" 4.0 loop 1 0 0 0 time -1
0605: actor 7@ perform_animation_sequence "DAN_LOOP_A" IFP_file "DANCING" 4.0 loop 1 0 0 0 time -1
0605: actor 8@ perform_animation_sequence "DAN_LOOP_A" IFP_file "DANCING" 4.0 loop 1 0 0 0 time -1

0A99: chdir 1 
0AAC: 0@ = load_mp3 "User Tracks\mymusic.mp3" 
// non occorre attendere il caricamento, per i file suoni.
0AAD: set_mp3 0@ perform_action 1

:EXIT
0001: wait 0
if
00FE:   actor $PLAYER_ACTOR sphere 0 in_sphere 757.74 -2840.03 10.68 radius 100.0 100.0 100.0
004D: jump_if_false @END
0002: jump @EXIT

:END
009B: destroy_actor 1@
009B: destroy_actor 2@
009B: destroy_actor 3@
009B: destroy_actor 4@
009B: destroy_actor 5@
009B: destroy_actor 6@
009B: destroy_actor 7@
009B: destroy_actor 8@
0249: release_model #WMYST
0249: release_model #WMYST
0249: release_model #WMYST
0249: release_model #WMYST
0249: release_model #WMYST
0249: release_model #WMYST
0249: release_model #WMYST
0249: release_model #WMYST

04EF: release_animation "DANCING"

0AAD: set_mp3 0@ perform_action 0
0AAE: release_mp3 0@
0A99: chdir 0

0A93: end_custom_thread

[Wesser]

La programmazione si fonda sulla logica per antonomasia, quindi adottare uno "stile" a basso livello a scapito di costrutti ad alto livello quando questi ultimi sono supportati è da meri masochisti. Inoltre, i wait (indispensabili all'interno di un ciclo per prevenire che il gioco vada in loop) vanno usati con il contagocce e con cognizione di causa per evitare ritardi indesiderati nell'esecuzione dello script, poiché anche un valore pari a 0 comporta lo slittamento della processazione dei comandi successivi al wait alla prossima elaborazione dello script (il cui lasso di tempo ammonta a qualche decimo di secondo, per questioni di ottimizzazione). Prendendo in esame il nostro caso, una risorsa (modello, animazione e via discorrendo) potrebbe anche essere caricata istantaneamente ed aggiungere un wait prima delle condizioni che verificano l'avvenuto caricamento è soltanto controproducente. Una volta caricato il modello, lo spawn non influenza il momento di disponibilità delle funzionalità dell'entità creata, per cui attendere ulteriormente dopo il suo verificarsi è anch'esso inutile. Infine (la chicca meno rilevante), il comando da te utilizzato che controlla la vicinanza o meno a determinate coordinate esegue dei calcoli sulla base delle dimensioni di un ellissoide, non di un cubo.

Messaggio modificato da Wesser il 09 luglio 2015 - 15:32

[GiangiaRab56]

Ciao ragazzi, ho un problema con questo script che genera il pedone a inizio partita (sono alle prime armi).

Ho un problema riguardo la parte Actor.DestroyInstantly. Una volta ucciso il pedone esso non scompare (ho atteso pure più di 2 minuti!), qualcuno sa come correggere questo problema? Grazie.

Vi posto tutto lo script:

{$CLEO .cs}


thread 'pazzo'


:prova_55
wait 250
model.Load(#DWMOLC2)
Model.Load(#CHNSAW)
038B: load_requested_models
00D6: if
00ED: actor $PLAYER_ACTOR sphere 0 near_point 2260.3196 -1260.7180 23.9744 radius 2260.3196 -1260.7180 23.9744 on_foot
else_jump @prova_55
009A: 3@ = create_actor_pedtype 4 model #DWMOLC2 at 2260.3196 -1260.7180 23.9744
01B2: give_actor 3@ weapon 9 ammo 1
02E2: set_actor 3@ weapon_accuracy_to 100
0850: AS_actor 3@ follow_actor $PLAYER_ACTOR
05E2: AS_actor 3@ kill_actor $PLAYER_ACTOR
087E: set_actor 3@ weapon_droppable 1
0223: set_actor 3@ health_to 100000
0446: set_actor 3@ dismemberment_possible 0
0946: set_actor 3@ actions_uninterupted_by_weapon_fire 1




:prova_22
wait 5000
if
Actor.Animation(3@) == "RUN_CIVI"
else_jump @prova_22
0393: actor 3@ perform_animation "RUN_CIVI" at 3.0 times_normal_rate
jump @prova_22

:die
wait 500
if
Actor.Dead(3@)
else_jump @die
Actor.DestroyInstantly(3@)
jump @die


end_thread

[Wesser]

Dovresti rimuovere il riferimento al pedone dalla pool con il comando seguente:

Actor.RemoveReferences(3@)

Attento ai valori settati per i wait, sono troppo elevati: il quantitativo di millisecondi impostato va ponderato scientemente. Inoltre, il salto incondizionato al label prova_22 va eliminato, altrimenti il codice sottostante non verrebbe mai eseguito, così come quello al label die.

[Automan]

C'è un solo wait che non conviene sia 0, tutti gli altri wait non serve siano più di 0.
Wait serve soprattutto per ridare il controllo al 'sistema principale', così può eseguire
meglio le istruzioni degli altri script.
Un wait da colcolare bene, da e oltre i 100 ms, è dopo tutte le istruzioni 'create', perché
il gioco impiega tempo a creare il ped/oggetto/quello_che_è, ma lo script continua,
e non aspetta l'effettiva creazione.

E' fatto obbligo di piazzare un wait prima degli if, specie se sono nella forma:

:M1a0
0001: wait 0 ms
if
00FE:   actor $PLAYER_ACTOR sphere 0 in_sphere 2364.2 2377.5 10.8 radius 100.0 100.0 100.0
004D: jump_if_false @M1a0

(Personalmente preferisco gli opcode con il loro ID, e non la forma libera alla VB, ma è un mio vezzo! )

Ho riscontrato un problema con Cleo4, tanto per, per quanto riguarda i file missione .cm,
richiamati da un script .cs: In Sanny Builder 322 occorre togliere la spunta nelle opzioni su "Aggiungi informazione extra", perché lo script può diventare troppo lungo e crasha.
Tuttavia, lo stesso .cm in Cleo3, con le informazioni aggiuntive, non solo funziona,
ma è molto più veloce.

[GiangiaRab56]

Grazie a entrambi della risposta, ora il problema non persiste più. Ma allora il comando Jump quando andrebbe utilizzato? Per passare da un label all'altro oppure ,appunto, per saltare (non eseguire) quella funzione? Grazie ancora per le vostre risposte.

[Automan]

Il 'jump' del linguaggio 'meraviglioso' di GTA non è altro che il 'goto' del vecchio basic.
Serve soprattutto per non fare/fare eseguire un pezzo di codice in base ad una condizione if.
Come hai ben intuito.
Saltare da un pezzo all'altro ha poco senso, però, se non per una specifica condizione.

(La forma più evoluta è il 'gosub', che è una parte di codice che piene eseguita più volte,
e si evita così di ripeterla più volte. Il programma riconosce da quale gosub è stato chiamato,
e torna lì).

...
0050: gosub @save_lev1
...
...
:save_lev1
0001: wait 0 ms

Player.CanMove($PLAYER_CHAR) = False

00BA: show_text_styled GXT 'MTOR06G' time 2000 style 7 // Salva finché sei in tempo!!!
0001: wait 2000 ms

fade 0 100 
0169: set_fade_color_RGB 0 0 0
wait 100
03D8: show_save_screen 

:SAVE_La1
wait 0 
if 
83D9:   not save_done 
else_jump @SAVE_La2 
jump @SAVE_La1

:SAVE_La2
fade 1 100
0169: set_fade_color_RGB 0 0 0
wait 100
Player.CanMove($PLAYER_CHAR) = True

0051: return

Nota che certi wait non sono 0, perché il tempo di esecuzione non viene rispettato dagli opcode che dovrebbero farlo,
linguaggio come detto 'meraviglioso'.

Messaggio modificato da Automan il 23 maggio 2016 - 16:36

[GiangiaRab56]

Tutto chiaro, grazie mille. Siete stati gentilissimi tu e wesser, buona serata!

[Automan]

E' un piacere, se ti serve siamo qui.

[GiangiaRab56]

Ciao a tutti, scusate se disturbo ancora ! Potrei sapere come far aumentare il danno al pedone che ho fatto spawnare? (Vorrei che mi levasse,ad esempio con un pugno, più vita o armatura rispetto al dovuto) Grazie mille!

[Automan]

Bentornato!

Fondamentalmente:

// 29@ -> enemy actor
21@ = Actor.Health($PLAYER_ACTOR)
0085: 20@ = 21@ // (int)

:mazzeeete
0001: wait 0 ms
if
051A:  actor $PLAYER_ACTOR damaged_by_actor 29@
004D: jump_if_false @mazzeeete

000E: 20@ -= 1 // meno quello che vuoi
Actor.Health($PLAYER_ACTOR) = 20@
0002: jump @mazzeeete

Dovresti prima verificare che l'armatura non sia zero,
e diminuire quella, prima di passare alla vita.

Messaggio modificato da Automan il 01 febbraio 2017 - 11:01

[GiangiaRab56]

Grazie mille . Ora ho anche visto tutti gli opcodes che si possono vedere con ctrl+alt+2 (me ne ero dimenticato). Sempre disponibili e gentilissimi, grazie

[Paolo1977]

Aiuto. Devo fare uno script di auto parcheggiate. Ma non va. Cosa sbaglio? Ho guardato un sacco di guide ma non ho risolto.
Ecco il codice:
{$CLEO .cs}
:nome1
name_thread 'PHOENIX'

:PHOENIX11
wait 0 ms
if
00EC: actor $PLAYER_ACTOR sphere 0 near_point 1244.7858 -779.9432 radius 40.0 40.0
jf @PHOENIX11
Model.Load(#PHOENIX)
038B: load_requested_models
0@ = Car.Create(#PHOENIX, 1244.7858, -779.9432, 90.3789)
Car.Angle(0@) = 359
0229: set_car 0@ primary_color_to 3 secondary_color_to 3
end_thread

[Automan]

Benvenuto!

A me funzia, ma provalo così:

{$CLEO .cs}
:nome1
thread 'PHOENIX'

:PHOENIX11
wait 0 ms
if
00EC: actor $PLAYER_ACTOR sphere 0 near_point 1244.7858 -779.9432 radius 40.0 40.0 
jf @PHOENIX11

Model.Load(#PHOENIX)
:load
0001: wait 0 ms
00D6: if
0248: model #PHOENIX available
004D: jump_if_false @load

0@ = Car.Create(#PHOENIX, 1244.7858, -779.9432, 90.3789)
Car.Angle(0@) = 359
0229: set_car 0@ primary_color_to 3 secondary_color_to 3

end_thread